Private Sub Form_Load()
Dim dx%, dy%
'Set From Position, Check ADVSET.INI , Get ADVSET.INI's Data

dx% = (Screen.Width - Me.Width) / 2
dy% = (Screen.Height - Me.Height) / 2
Me.Move dx%, dy%

If Dir$(workPath$ & "ADVSET.INI") <> "" Then
   If GetIntFromIni("START", "ACTION", -1, workPath$ & "ADVSET.INI") <> -1 Then
      chkScrSet.Value = GetIntFromIni("START", "ACTION", 0, workPath$ & "ADVSET.INI")
      txtDelayTime.Text = GetStringFromIni("START", "DELAYTIME", "1", workPath$ & "ADVSET.INI")
      txtProFileName.Text = GetStringFromIni("START", "PROFILE", "", workPath$ & "ADVSET.INI")
   End If
End If
End Sub

Private Sub cmdOK_Click()
Dim rBuf$, ShortName$, rc&

'1.Check Set Value Error,If Error Flase Then Write Data To ADVSET.INI
'2.If Scr File Not Find then Copy Scr File
'3.Set Screen Saver TimeOut,Check OS ver,Set Screen Saver Active

If CInt(Val(txtDelayTime.Text)) <= 0 Then
   MsgBox "等候時間不可為零值", vbOKOnly Or vbInformation
   Exit Sub
End If

If Trim$(txtProFileName) = "" Then
   MsgBox "必須指定使用的設定檔", vbOKOnly Or vbInformation
   Exit Sub
End If

If Dir$(txtProFileName) = "" Then
   MsgBox "找不到您指定的設定檔", vbOKOnly Or vbInformation
   Exit Sub
End If

If Dir$(workPath$ & "ScrMaker.Exe") = "" Then
   MsgBox "找不到預設的執行檔名！請確定目前執行的檔案名稱為 ScrMaker.Exe，否則無法正常的設定螢幕保護程式", vbOKOnly Or vbInformation
   Exit Sub
End If

rBuf$ = workPath
WriteStringToIni "START", "ACTION", Trim$(Str$(chkScrSet.Value)), workPath & "ADVSET.INI"
WriteStringToIni "START", "DELAYTIME", txtDelayTime.Text, workPath & "ADVSET.INI"
WriteStringToIni "START", "PROFILE", txtProFileName.Text, workPath & "ADVSET.INI"


If Dir$(workPath$ & "ScrMaker.Scr") = "" Then
   FileCopy workPath$ & "ScrMaker.Exe", workPath & "ScrMaker.Scr"
End If

SystemParametersInfo SPI_SETSCREENSAVETIMEOUT, CLng(Val(txtDelayTime.Text)) * 60, 0&, SPIF_UPDATEINIFILE Or SPIF_SENDWININICHANGE

Dim ver As OSVERSIONINFO, hkey As Long, Length As Long
ver.dwOSVersionInfoSize = Len(ver)
GetVersionEx ver

ShortName = String(LenB(workPath & "ScrMaker.Scr"), Chr$(0))
rc = GetShortPathName(workPath & "ScrMaker.Scr", ShortName, Len(ShortName))


If ver.dwPlatformId = VER_PLATFORM_WIN32_NT Then    'Windows NT
   
   RegOpenKey HKEY_CURRENT_USER, "Control Panel\Desktop", hkey
   RegSetValueEx hkey, "SCRNSAVE.EXE", 0, REG_SZ, ByVal (winPath$ & "ScrMaker.Scr"), Length
   RegCloseKey hkey

Else    'Windows95 / 98

   WriteStringToIni "boot", "SCRNSAVE.EXE", ShortName$, winPath$ & "system.ini"

End If

SystemParametersInfo SPI_SETSCREENSAVEACTIVE, CLng(True), 0&, SPIF_UPDATEINIFILE Or SPIF_SENDWININICHANGE

MsgBox "設定成功！", vbOKOnly Or vbInformation
Unload Me
End Sub

Private Sub Form_Load()
Dim dx%, dy%, rBuf$, i%, ShortName$, rc&, hkey&
'Set From Position, Check ADVSET.INI , Get ADVSET.INI's Data,Get All Screen Saver Data

'略

GetScrData這一段副程式是用來找出我們的電腦裡有那些.Scr的螢幕保護程式，
並將其List在lstListSCR裡，這一段比較簡單，我就省略不講了，不過，我搜尋的
範圍僅限於Windows及System的目錄，這一點請注意

Call GetScrData

If Dir$(workPath$ & "ADVSET.INI") <> "" Then
   i = GetIntFromIni("START", "ACTION", -1, workPath$ & "ADVSET.INI")


   首先，因為設定劃分為兩大區的緣故，我們必須Check ADVSET.INI的內容，
   以確定要載入的資料及控制項Enabled的控制，先確定是否是將Screen Saver Maker設定為啟動
   如果是啟動的話，在讀取出各項資料，去設定各控制項，在讀取及設定時有幾點要注意的，
   第一點是check box這個控制項，在你改變check box的value時，也會引起Click的事件
   所以，如果你在Click如果有做任何事的話，就要想辦法把這一段避過去，我是使用chkSkip的變數，
   藉此來判斷到底要不要執行Click事件的程式，接者，我們要判斷目前有沒有設定密碼，如果有
   就必須為chkSetPwd的控制項打勾(value=vbChecked)，判斷的方法很簡單，從登錄檔的資料下手，
   HKEY_CURRENT_USER\Control Panel\Desktop\ScreenSaveUsePassword
   只要讀取這個Key的值就可以了，如果等於1就是有設定密碼
   另外將setPasswdFlag設為WN_SUCCESS，這個變數是用來設定有沒有設定密碼的
   後面會做詳細一點的說明
   最後，我們再從載入的專案檔副檔名判斷要將那些控制項Enabled
   並呼叫EnabledControl()來執行，並設定setLoadType，讓我們知道目前載入的設定為何
   LOAD_SPM   SPM專案檔
   LOAD_SPC   SPC專案檔
   LOAD_NONE  一般的螢幕保護程式

   If i <> 0 And i <> -1 Then
      chkSkip = 1
      chkScrSet.Value = GetIntFromIni("START", "ACTION", 0, workPath$ & "ADVSET.INI")
      chkSkip = 0
      chkEscQuit.Value = GetIntFromIni("START", "ESC_QUIT", 0, workPath$ & "ADVSET.INI")
      txtDelayTime.Text = GetStringFromIni("START", "DELAYTIME", "1", workPath$ & "ADVSET.INI")
      rBuf$ = GetStringFromIni("START", "PROFILE", "", workPath$ & "ADVSET.INI")
      
      chkSetPwd.Enabled = True
      RegOpenKey HKEY_CURRENT_USER, "Control Panel\Desktop", hkey
      RegQueryValueEx hkey, "ScreenSaveUsePassword", 0, REG_DWORD, rc, 4
      RegCloseKey hkey
      If rc = 1 Then
         chkSetPwd.Value = vbChecked
         setPasswdFlag = WN_SUCCESS
      Else
         chkSetPwd.Value = vbUnchecked
         setPasswdFlag = 1
      End If
      
      
            
      If UCase$(Right$(rBuf$, 3)) = "SPC" Then
         Call EnabledControl(SCRMAKER, LOAD_SPC)
         Call GetSPCData(rBuf$)
         txtSPCFileName.Text = rBuf$
      Else
         Call EnabledControl(SCRMAKER, LOAD_SPM)
         txtProFileName.Text = rBuf$
      End If
   Else
      Call EnabledControl(NORMAL_SCR, LOAD_NONE)
   End If
Else
   Call EnabledControl(NORMAL_SCR, LOAD_NONE)
End If


接下來，如果是載入Screen Saver Maker的專案檔，就可以離開這一段程式了
如果是載入一般的螢幕保護程式的話，則必須利用API找出ScreenSaver的名稱
及等待的時間，再設定到相對應的控制項即可

SPCUpdate = False
If setLoadType <> LOAD_NONE Then
   tmpScrFileName = ""
Else
   RegOpenKey HKEY_CURRENT_USER, "Control Panel\Desktop", hkey
   RegQueryValueEx hkey, "ScreenSaveUsePassword", 0, REG_DWORD, rc, 4
   RegCloseKey hkey
   
   If rc = 1 Then
      chkSetPasswd.Value = vbChecked
      setPasswdFlag = WN_SUCCESS
   Else
      chkSetPasswd.Value = vbUnchecked
      setPasswdFlag = 1
   End If

   tmpScrFileName = GetStringFromIni("boot", "SCRNSAVE.EXE", "", winPath$ & "system.ini")
   If tmpScrFileName = "" Then
      lstSCRList.Selected(0) = True
      txtDelayTime.Text = "1"
   Else
      For i = 0 To UBound(ScrFileName)
          ShortName = String(LenB(ScrFileName(i)), Chr$(0))
          rc = GetShortPathName(ScrFileName(i), ShortName, Len(ShortName))
          ShortName = Left$(ShortName, InStr(1, ShortName, Chr(0)) - 1)
          
          If tmpScrFileName = ShortName Then
             lstSCRList.Selected(i + 1) = True
             Exit For
          End If
      Next i
      If i = UBound(ScrFileName) + 1 Then
         lstSCRList.Selected(0) = True
         txtDelayTime.Text = "1"
      Else
         SystemParametersInfoByRef SPI_GETSCREENSAVETIMEOUT, 0, rc, 0
         txtDelayTime.Text = rc \ 60
      End If

   End If
End If
End Sub

'[This is Screen saver maker Program file Colletcion]
'[Please Don't Modify This File]
'[請不要任意變更此檔案的內容，否則可能造成系統錯誤]
SUM=002
C:\MYWORK\Screen Saver Maker\Di Gi Charat.SPM
C:\WALL\OrangeRoad\Orange Road.SPM

Private Sub Form_Activate()
Dim rc As Long
'Hide Mouse Cursor,Set Window TopMost,Reset Midi and Wave Flag

rc = ShowCursor(False)
rc = SetWindowPos(Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE)
ReplayMidiFlag = 0
ReplayWavFlag = 0
frmActive.cmdStart.Value = True
End Sub

Private Sub cmdStart_Click()
'Check ActiveType
'1.PreView -> Load Picture File then GetEffectTime then Show Picture
'2.Start -> Get Default Screen Saver's SPM File,Goto tmrActive
'3.Program Test -> Get Define SPM File, Check SPM Error,Goto tmrActive

If ActiveType = Active_PicPreview Then
   Call LoadImagePicture(frmScrSetUP.chkFullPic.Value)
ElseIf ActiveType = Active_Start Then
   Call LoadSPMData("")
   tmrActive.Interval = 250
   tmrActive.Enabled = True
   Exit Sub
ElseIf ActiveType = ProgramTest Then
   Call LoadSPMData(ProFileTemp$)
   If ActiveType <> DefaultAction Then ActiveType = Active_Start
   tmrActive.Interval = 250
   tmrActive.Enabled = True
   Exit Sub
End If

picPreView.AutoRedraw = True
Call GetEffectTime

tmrShow.Enabled = True
End Sub

Private Sub LoadImagePicture(FullType As Integer)
Dim i As Integer

'1.Load Picture File Set the prePicture Width & Height
'2.Check Picture's ShowType (Full or Normal) , Get Source & Target's Width,Height,Left,Top
'3.If Error Then Set loopNo = 0

On Error GoTo ImageError_Handle

picPreView.Picture = LoadPicture(picName)

preWidth = DestWidth
preHeight = DestHeight

If FullType = vbChecked Or (picPreView.ScaleWidth = screenWidth And picPreView.ScaleHeight = screenHeight) Then
   
   SrcTop = 0
   SrcLeft = 0
   SrcWidth = picPreView.ScaleWidth
   SrcHeight = picPreView.ScaleHeight
   DestTop = 0
   DestLeft = 0
   DestWidth = screenWidth
   DestHeight = screenHeight
      
   picCut = False
Else
   If picPreView.ScaleWidth > screenWidth Then
      If picPreView.ScaleWidth - screenWidth > 1 Then
         SrcLeft = (picPreView.ScaleWidth - screenWidth) / 2
      Else
         SrcLeft = 0
      End If
      SrcWidth = screenWidth
      DestLeft = 0
      DestWidth = screenWidth
      
   Else
      SrcLeft = 0
      SrcWidth = picPreView.ScaleWidth
      If screenWidth - picPreView.ScaleWidth > 1 Then
         DestLeft = (screenWidth - picPreView.Width) / 2
      Else
         DestLeft = 0
      End If
      DestWidth = picPreView.ScaleWidth

   End If
   
   If picPreView.ScaleHeight > screenHeight Then
      If picPreView.ScaleHeight - screenHeight > 1 Then
         SrcTop = (picPreView.ScaleHeight - screenHeight) / 2
      Else
         SrcTop = 0
      End If
      SrcHeight = screenHeight
      DestTop = 0
      DestHeight = screenHeight
   
   Else
      SrcTop = 0
      SrcHeight = picPreView.ScaleHeight
      If screenHeight - picPreView.ScaleHeight > 1 Then
         DestTop = (screenHeight - picPreView.ScaleHeight) / 2
      Else
         DestTop = 0
      End If
      DestHeight = picPreView.ScaleHeight
   
   End If
   
   picCut = True
End If

loopNo = 1
Exit Sub

ImageError_Handle:
    loopNo = 0
    Resume QuitImageError
    
QuitImageError:
    Exit Sub
End Sub